Your source for ASP-related frequently asked questions and answers! : ASP FAQS : FileSystemObject

Question: How can I create a file with a random file name?

Answer: There are oftentimes when developers need to create a temporary text file whose usefulness usually extends only for a short period of time. For example, in Creating Excel Spreadsheets with Office Web Components (OWC), a dynamically generated Excel spreadsheet is created each time a user visits a page. Imagine what might happen if, for every visitor to the page, an Excel spreadsheet was created with a single, hard-coded filename (say Results.xls). UserA might visit the ASP page that generates a personal Excel spreadsheet named Results.xls, which can be downloaded. If between the time UserA generates the spreadsheet and when UserA actually gets around to downloading the file, what would happen if UserB comes in and hits the same page, generating his own Excel spreadsheet with the same file name (Results.xls)? When UserA went to download his spreadsheet, he would see the result of UserB's query! Egad.

Fortunately the FileSystemObject contains a couple of methods to help us create temporary/random/unique file names. The first method, GetTempName, returns a temporary file name. For example, the code:

  Dim objFSO
  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  Response.Write objFSO.GetTempName

  Set objFSO = Nothing 'Clean up!

Might output: rad295F4.tmp
or: rad4ED11.tmp
or: radC6F92.tmp

The thing to note is that a random (temporary) file name will be generated from the method. Note that this method does not create a file, it just returns a file name that can be used to create a temporary file. (View the technical docs for GetTempName.)

The GetTempName method only returns a file name, though. If you want to grab the official Windows temporary folder you can use the GetSpecialFolder method of the FileSystemObject. This method expects one parameter, the specific "special folder" path to return. This parameter can accept one of three values:

0 - Returns the Windows folder (like C:\WINNT\)
1 - Returns the system folder (most likely C:\WINNT\system32)
2 - Returns the temporary folder (like C:\WINNT\Temp)

Of course we should strive to not use magic numbers, but rather define constants for the values of 0, 1, and 2. The code below shows how to use the GetSpecialFolder method to return the name of the temporary folder and how to use the GetSpecialFolder method in conjunction with the GetTempName method to return a fully functioning temporary folder/file name.

  Const fsoTempFolder = 2

  Dim objFSO
  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

  Dim strTempFolder, strTempFileName
  strTempfolder = objFSO.GetSpecialFolder(fsoTempFolder)

  strTempFileName = strTempFolder & "\" & objFSO.GetTempName()

  Response.Write "The temporary folder is: " & strTempFolder
  Response.Write "<br>A temp. file name: " & strTempFileName

  Set objFSO = Nothing 'Clean up!

The output of the above script might be:
The temporary folder is: C:\WINNT\Temp
A temp. file name: C:\WINNT\Temp\rad604B8.tmp

(View the technical docs for GetSpecialFolder.)

For an interesting example of using the GetTempName method to create random passwords check out: A Quick and Dirty Random Password Generator.

Happy Programming!

FAQ posted by Scott Mitchell at 3/6/2001 5:21:20 AM to the FileSystemObject category. This FAQ has been viewed 58,382 times.

Copyright 2017 QuinStreet Inc. All Rights Reserved.
Legal Notices, Licensing, Permissions, Privacy Policy.
Advertise | Newsletters | E-mail Offers