When you think ASP, think...
Recent Articles
All Articles
ASP.NET Articles
ASPFAQs.com
Message Board
Related Web Technologies
User Tips!
Coding Tips

Sections:
Sample Chapters
Commonly Asked Message Board Questions
JavaScript Tutorials
MSDN Communities Hub
Official Docs
Security
Stump the SQL Guru!
XML Info
Information:
Feedback
Author an Article
ASP ASP.NET ASP FAQs Message Board Feedback

The 4 Guys Present: ASPFAQs.com

Jump to a FAQ
Enter FAQ #:
..or see our 10 Most Viewed FAQs.

4GuysFromRolla.com : ASP FAQS : Arrays


Question:

How can I determine the position of a particular string in an Array?


[Print this FAQ]

Answer: A very simple way of determining whether or not a string exists in an array is to use a loop, checking each element:

Dim iLoop, iPos
iPos = -1

For iLoop = LBound(SomeArray) to UBound(SomeArray)
  If CStr(SomeString) = CStr(SomeArray(iLoop)) then
    'We found the element
    iPos = iLoop
  End If
Next

At this point, iPos will equal the position that SomeString was found in SomeArray, or, if the string was not found in the array, iPos will equal -1.

While the above code is satisfactory, why not encapsulate it in a function so that we can easily reuse it? Also, another potential problem: how are we wanting to compare the string value to the elements in the array? If we are looking for the string "FooBar" in an array, are we content if we find "Foobar", or do we care about the case?

With that being said, I propose the following function be used to quickly determine the position an element exists in an array:

Function PositionInArray(aMyArray, strLookingFor, compare)
'Return the position strLookingFor is found in aMyArray... if
'strLookingFor is not found, -1 is returned.

  Dim iUpper, iLoop
  iUpper = UBound(aMyArray)

  For iLoop = LBound(aMyArray) to iUpper
    If compare = vbTextCompare then
      If CStr(UCase(aMyArray(iLoop))) = CStr(UCase(strLookingFor)) then
        PositionInArray = iLoop
        Exit Function
      End If
    Else
      If CStr(aMyArray(iLoop)) = CStr(strLookingFor) then
        PositionInArray = iLoop
        Exit Function
      End If
    End If
  Next

  'Didn't find the element in the array...
  PositionInArray = -1

End Function

Note that our function expects three parameters: aMyArray, the string array that we are searching; strLookingFor, the string that we are looking for in the array aMyArray; and compare, which indicates if we are wanting to do a case-sensitive search (vbBinaryCompare) or a case-insensitive search (vbTextCompare).

Here is an example program for which the above function can be used:

<%
  '******* INCLUDE ABOVE FUNCTION IN CODE HERE **********

  Dim aSomeArray
  aSomeArray = Array("I", "think", "ASP", "is", "cool!")

  Response.Write PositionInArray(aSomeArray, "I", vbBinaryCompare) & "<BR>"
  Response.Write PositionInArray(aSomeArray, "foo", vbBinaryCompare) & "<BR>"
  Response.Write PositionInArray(aSomeArray, "ASP", vbBinaryCompare) & "<BR>"
  Response.Write PositionInArray(aSomeArray, "bar", vbBinaryCompare) & "<BR>"
  Response.Write PositionInArray(aSomeArray, "Cool!", vbTextCompare) & "<BR>"
%>

Output is:
0
-1
2
-1
4


Happy Programming!


FAQ posted by Scott Mitchell at 11/26/2000 2:11:12 PM to the Arrays category. This FAQ has been viewed 58,403 times.

Do you have a FAQ you'd like to suggest? Suggestions? Comments? If so, send it in! Also, if you'd like to be a FAQ Admin (creating/editing FAQs), let me know! If you are looking for other FAQs, be sure to check out the 4Guys FAQ and Commonly Asked Messageboard Questions!

Most Viewed FAQs:

1.) How can I format numbers and date/times using ASP.NET? For example, I want to format a number as a currency. (761643 views)
2.) I am using Access and getting a 80004005 error (or a [Microsoft][ODBC Microsoft Access Driver] The Microsoft Jet database engine cannot open the file '(unknown)' error) when trying to open a connection! How can I fix this problem? (207777 views)
3.) How can I convert a Recordset into an array? Also, how can I convert an array into a Recordset? (202549 views)
4.) How can I quickly sort a VBScript array? (196039 views)
5.) How can I find out if a record already exists in a database? If it doesn't, I want to add it. (156019 views)
6.) How do I display data on a web page using arrays instead of Do...While...MoveNext...???... (152331 views)
7.) When I get a list of all files in a directory via the FileSystemObject, they aren't ordered in any reasonable way. How can I sort the files by name? Or by size? Or by date created? Or... (140381 views)
8.) For session variables to work, must the Web visitor have cookies enabled? (110162 views)
9.) Can I send emails without using CDONTS? (107083 views)
10.) How can I take the result of a SELECT...MULTIPLE or a group of same-named checkboxes and turn it into a query? That is, if the user selects 3 answers, how can I construct a query that looks for all 3? (106308 views)
Last computed at 9/17/2007 3:22:00 AM


ASP.NET [1.x] [2.0] | ASPMessageboard.com | ASPFAQs.com | Advertise | Feedback | Author an Article