
<%@ Language=VBScript %>
<% Option Explicit %>
<%
	Dim objConn
	Set objConn = Server.CreateObject("ADODB.Connection")
	objConn.Provider = "MSDataShape"
	objConn.Open "DSN=University"
	
	Dim objClassRS, objProfessorRS, objProjectRS, objTextBookRS
		
	Dim strShapeSQL
	strShapeSQL = "SHAPE {SELECT ProfessorID, FirstName, LastName, PhoneNumber " & _
					" FROM Professor}" & _
			" APPEND((SHAPE {SELECT ClassID, ClassName, RefNumber, ProfessorID FROM Class} AS Class " & _
				"APPEND({SELECT Title, Price, ClassID FROM TextBook} AS Book " & _
				"RELATE ClassID TO ClassID)) " & _
			" RELATE ProfessorID TO ProfessorID), " & _
			" ({SELECT Title, ProfessorID FROM Project} AS Project " & _
			" RELATE ProfessorID TO ProfessorID)"
	
	Set objProfessorRS = Server.CreateObject("ADODB.Recordset")
	objProfessorRS.Open strShapeSQL, objConn
	
	Do While Not objProfessorRS.EOF
		Response.Write "<BR>"
		Response.Write objProfessorRS("FirstName") & " "
		Response.Write objProfessorRS("LastName") & _
				" (Phone: " & objProfessorRS("PhoneNumber") & ")<BR>"
		
		Response.Write "&nbsp;&nbsp;&nbsp;<B>Classes:</B><BR>"
		Set objClassRS = objProfessorRS("Class").Value
		Do While Not objClassRS.EOF
			Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;" & _
					objClassRS("ClassName") & _
					" (" & objClassRS("RefNumber") & ")<BR>"

			Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;Books:<BR>"
			Set objTextBookRS = objClassRS("Book").Value
			If objTextBookRS.EOF then
				Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;None...<BR>"
			Else
				Do While Not objTextBookRS.EOF
					Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;&nbsp;" & _
						objTextBookRS("Title") & " (" & _
						FormatCurrency(objTextBookRS("Price")) & ")<BR>"

					objTextBookRS.MoveNext
				Loop
			End If

			objClassRS.MoveNext
		Loop

		Response.Write "&nbsp;&nbsp;&nbsp;<B>Projects:</B><BR>"	
		Set objProjectRS = objProfessorRS("Project").Value
		Do While Not objProjectRS.EOF
			Response.Write "&nbsp;&nbsp;&nbsp;&nbsp;" & _
					objProjectRS("Title") & "<BR>"
			objProjectRS.MoveNext
		Loop

		objProfessorRS.MoveNext
	Loop

	objProfessorRS.Close
	Set objProfessorRS = Nothing
	
	
	objConn.Close
	Set objConn = Nothing
%>