
<%@ Language=VBScript %>
<%
	'Always do this: (good programming practice!)
	Option Explicit
	'Declare our FileSystemObject variable
	Dim objFSO
	Set objFSO = Server.CreateObject("Scripting.FileSystemObject")

	Dim objFolder
	

	Dim strCurrentFolder
	strCurrentFolder = "C:\Inetpub\wwwroot\"
	
	Set objFolder = objFSO.GetFolder(strCurrentFolder)
	
	'Declare a file object
	Dim objFile
	
	'What is the maximum size of a file in bytes?
	Const MaxSize = 5000  '50 KB


	'Did we find any violating files?
	Dim bolViolators
	bolViolators = False

	'Now, use a for each...next to loop through the Files collection
	For Each objFile in objFolder.Files
	    'Check to see if objFile is an MP3
	    If LCase(Right(objFile.Name, 4)) = ".mp3" then
			'Print out the violating file name and location
			Response.Write "<B>MP3 File!</B><BR>"
			Response.Write objFile.Path & "<P>"

			'We found a violator
			bolViolators = True
	    End if

	    'Make sure the file isn't too big
	    If objFile.Size > MaxSize then
			'Print out the violating file name and location
			Response.Write "<B>File is too large! (" & objFile.Size & " bytes)</B><BR>"
			Response.Write objFile.Path & "<P>"

			'We found a violator
			bolViolators = True
	    End If
	Next

	'Now, if we didn't have any violating files, say so!
	If Not bolViolators then
		Response.Write "No violating Files..."
	End if	

	'Clean up...
	Set objFSO = Nothing
	Set objFolder = Nothing	
%>