
<% 
Function ShowServices(vComputerName, vClass) 

  Dim objLocator, objService, objWEBMCol, objWEBM, objProp, propitem, objItem
  Set objLocator = CreateObject("WbemScripting.SWbemLocator") 

  'Establish a connection to WMI 
  If isEmpty(vComputerName) = True then 
     Set objService = objLocator.ConnectServer 
  Else 
     Set objService = objLocator.ConnectServer(vComputerName) 
  End If 

  'Get the Webm class object 
  Set objWEBM = objService.get(vclass)

  'get collection of class
  set objWEBMCol = objWEBM.Instances_

  'Get ref to properties of obj
  set objProp = objWebm.properties_

  response.write "<table BORDER='1'>   <tr>" &chr(13)
  for each propItem in objProp
    response.write "<th>"&propItem.name&"</th>"&chr(13)
  next
  response.write "</tr>"&chr(13)

  'Enumerate 
  For Each objItem in objWEBMCol 
    response.write "<tr>"&chr(13)

    for each propItem in objProp
      response.write "<td>"

      response.write eval("objItem."&propItem.name)

      response.write "</td>"&chr(13)
    next

    response.write "</tr>"&chr(13)
  Next 

  response.write "</table>"

  'Clean up 
  Set objLocator = Nothing 
  Set objService = Nothing 
  Set objWEBMCol = Nothing 
  Set objWEBM = Nothing 
  set objProp = nothing
End Function 


Call ShowServices("", "Win32_Processor") 
%>