Using the FileSystemObject to Write to Text Files
In the previous FAQ, we discussed how the FileSystemObject and
TextStream objects could be used to read the contents of a text file. In this FAQ, we will
discuss how to write to a text file using these two objects.
Recall that we Opened a text file using the OpenTextFile method of the FileSystemObject
object. In the previous FAQ we talked about two parameters into this function. When dealing with writing
text files, we need to discuss the third. This third parameter is optional, like the second, and is a
boolean value. The new definition of the OpenTextFile method is:
FileSystemObjectInstance.OpenTextFile(FullFilePath[, iomode[, Created]])
|
Note: there is one more optional parameter, but we are only interested in these first three for the time
being.
The optional iomode parameter decides what IO mode the file is opened with. The following
values can be used:
iomode Values |
|---|
| ForReading | 1 |
| ForWriting | 2 |
| ForAppending | 8 |
These constants are not defined in a text file like the ADO constants are defined in
ADOVBS.inc. Therefore, you should define
the constant you wish to use. For example, if I use the ForReading constant, you
will see ASP code like:
The Create method determines whether or not a new file should be created if the specified
file name (FullFilePath) does not exist. Create defaults to False.
If you try to write to a file that doesn't exist, and Create is set to False (either
implicitly or explicitly), an error will occur.
The TextStream object has the following important methods for writing to text files:
Write(string) - Writes a string to the open text file.
WriteLine([string]) - Writes a string to the text file and finishes it off
with the new line character.
WriteBlankLines(lines) - Writes a specified number of new line characters.
Finally, the TextStream object has a Close method, which should be used when
you have finished writing to the file.
Now, let's look at how we could append a couple of lines to an existing text file, C:\Welcome.txt.
Const fsoForAppend = 8
Dim objFSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'Open the text file
Dim objTextStream
Set objTextStream = objFSO.OpenTextFile("C:\Welcome.txt", fsoForAppend)
'Display the contents of the text file
objTextStream.WriteLine "Hello, World!"
objTextStream.WriteLine "This is fun!!"
'Close the file and clean up
objTextStream.Close
Set objTextStream = Nothing
Set objFSO = Nothing |
Note that the Create parameter will be set to False here (since it is the
default). If the file C:\Welcome.txt does not exist, an error will occur. If the file
does exist, however, "Hello, World!" and "This is fun!" will be appended.
Now, what if we want to create a text file with the contents: "Hello, World!" The following code will
do that just fine:
Const fsoForWriting = 2
Dim objFSO
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'Open the text file
Dim objTextStream
Set objTextStream = objFSO.OpenTextFile("C:\SomeFile.txt", fsoForWriting, True)
'Display the contents of the text file
objTextStream.WriteLine "Hello, World!"
'Close the file and clean up
objTextStream.Close
Set objTextStream = Nothing
Set objFSO = Nothing |
Since Create is set to True, if C:\SomeFile.txt does not exist, the file will still
be created and "Hello, World!" will be written to the file. Neat, eh?
A closing note: when dealing with IIS, the permissions granted to IUSR_machinename
are important. For example, if you do not have write permission to the C drive for
IUSR_machinename, an error will occur in the above scripts.
Now that we've discussed how to read and write text files, two common file system operations, in our
next FAQ we will discuss another common file system operation: copying, moving,
and deleting files.
Happy Programming!
